DataInputStream

Object Hierarchy:

Description:

public static void write_data (DataOutputStream dos) throws GLib.IOError {
	dos.put_int16 (int16.MIN);
	dos.put_int32 (int32.MIN);
	dos.put_int64 (int64.MIN);

	dos.put_uint16 (uint16.MAX);
	dos.put_uint32 (uint32.MAX);
	dos.put_uint64 (uint64.MAX);

	dos.put_byte ('c');
	dos.put_string ("Northwest Passage");
	dos.put_byte ('\0');

	dos.put_string ("Barrett's Privateers");
	dos.put_byte ('\0');
}

public static void read_data (DataInputStream dis) throws GLib.IOError {
	print ("%d (Expected: %d)\n", dis.read_int16 (), int16.MIN);
	print ("%d (Expected: %d)\n", dis.read_int32 (), int32.MIN);
	print ("%"+int64.FORMAT+" (Expected: %"+int64.FORMAT+")\n", dis.read_int64 (), int64.MIN);

	print ("%u (Expected: %u)\n", dis.read_uint16 (), uint16.MAX);
	print ("%u (Expected: %u)\n", dis.read_uint32 (), uint32.MAX);
	print ("%"+uint64.FORMAT+" (Expected: %"+uint64.FORMAT+")\n", dis.read_uint64 (), uint64.MAX);

	print ("%c\n", dis.read_byte ());

	print ("%s\n", dis.read_upto ("\0", 1, null));
	dis.read_byte (); // Consume '\0'

	print ("%s\n", dis.read_upto ("\0", 1, null));
	dis.read_byte (); // Consume '\0'
}

public static async void read_data_async (DataInputStream dis) throws GLib.IOError {
	print ("%d (Expected: %d)\n", dis.read_int16 (), int16.MIN);
	print ("%d (Expected: %d)\n", dis.read_int32 (), int32.MIN);
	print ("%"+int64.FORMAT+" (Expected: %"+int64.FORMAT+")\n", dis.read_int64 (), int64.MIN);

	print ("%u (Expected: %u)\n", dis.read_uint16 (), uint16.MAX);
	print ("%u (Expected: %u)\n", dis.read_uint32 (), uint32.MAX);
	print ("%"+uint64.FORMAT+" (Expected: %"+uint64.FORMAT+")\n", dis.read_uint64 (), uint64.MAX);

	print ("%c\n", dis.read_byte ());

	print ("%s\n", yield dis.read_upto_async ("\0", 1, Priority.DEFAULT, null, null));
	dis.read_byte (); // Consume '\0'

	print ("%s\n", yield dis.read_upto_async ("\0", 1, Priority.DEFAULT, null, null));
	dis.read_byte (); // Consume '\0'
}

public static int main (string[] args) {
	try {
		// Create a file that can only be accessed by the current user:
		File file = File.new_for_path ("my-test.bin");
		FileIOStream ios = file.create_readwrite (FileCreateFlags.PRIVATE);

		// Write data:
		DataOutputStream dos = new DataOutputStream (ios.output_stream);
		write_data (dos);

		// Reset fp, read data:
		ios.seek (0, SeekType.SET);
		DataInputStream dis = new DataInputStream (ios.input_stream);
		read_data (dis);

		// Reset fp, read data async:
		ios.seek (0, SeekType.SET);

		MainLoop loop = new MainLoop ();
		read_data_async.begin (dis, () => {
			loop.quit ();
		});

		loop.run ();
	} catch (Error e) {
		print ("Error: %s\n", e.message);
	}

	return 0;
}

valac --pkg gio-2.0 GLib.DataInputStream.vala

Content:

Properties:

• public DataStreamByteOrder byte_order { get; set; }
  The byte_order property determines the byte ordering that is used when reading multi-byte entities (such as integers) from the stream.
• public DataStreamNewlineType newline_type { get; set; }
  The newline_type property determines what is considered as a line ending when reading complete lines from the stream.

Creation methods:

• public DataInputStream (InputStream base_stream)
  Creates a new data input stream for the base_stream.

Methods:

• public DataStreamByteOrder get_byte_order ()
  Gets the byte order for the data input stream.
• public DataStreamNewlineType get_newline_type ()
  Gets the current newline type for the this .
• public uint8 read_byte (Cancellable? cancellable = null) throws IOError
  Reads an unsigned 8-bit/1-byte value from this.
• public int16 read_int16 (Cancellable? cancellable = null) throws IOError
  Reads a 16-bit/2-byte value from this .
• public int32 read_int32 (Cancellable? cancellable = null) throws IOError
  Reads a signed 32-bit/4-byte value from this.
• public int64 read_int64 (Cancellable? cancellable = null) throws IOError
  Reads a 64-bit/8-byte value from this .
• public string? read_line (out size_t length = null, Cancellable? cancellable = null) throws IOError
  Reads a line from the data input stream.
• public async string? read_line_async (int io_priority = DEFAULT, Cancellable? cancellable = null, out size_t length = null) throws IOError
• public string? read_line_utf8 (out size_t length = null, Cancellable? cancellable = null) throws IOError
  Reads a UTF-8 encoded line from the data input stream.
• public async string? read_line_utf8_async (int io_priority = DEFAULT, Cancellable? cancellable = null, out size_t length = null) throws IOError
  The asynchronous version of read_line.
• public uint16 read_uint16 (Cancellable? cancellable = null) throws IOError
  Reads an unsigned 16-bit/2-byte value from this.
• public uint32 read_uint32 (Cancellable? cancellable = null) throws IOError
  Reads an unsigned 32-bit/4-byte value from this.
• public uint64 read_uint64 (Cancellable? cancellable = null) throws IOError
  Reads an unsigned 64-bit/8-byte value from this.
• public string read_until (string stop_chars, out size_t length, Cancellable? cancellable = null) throws IOError
  Reads a string from the data input stream, up to the first occurrence of any of the stop characters.
• public async string read_until_async (string stop_chars, int io_priority = DEFAULT, Cancellable? cancellable = null, out size_t length) throws IOError
  The asynchronous version of read_until.
• public string read_upto (string stop_chars, ssize_t stop_chars_len, out size_t length, Cancellable? cancellable = null) throws IOError
  Reads a string from the data input stream, up to the first occurrence of any of the stop characters.
• public async string read_upto_async (string stop_chars, ssize_t stop_chars_len, int io_priority = DEFAULT, Cancellable? cancellable = null, out size_t length) throws IOError
  The asynchronous version of read_upto.
• public void set_byte_order (DataStreamByteOrder order)
  This function sets the byte order for the given this.
• public void set_newline_type (DataStreamNewlineType type)
  Sets the newline type for the this.

Inherited Members: